-
Notifications
You must be signed in to change notification settings - Fork 1
/
noplug.init.vim
310 lines (269 loc) · 9.02 KB
/
noplug.init.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
" This is the portion of init.vim that is just mappings and autocmds, i.e.
" doesn't rely on any plugins. It ought to be sourced near the top of
" init.vim
" call plug#end() also executes the following lines, but since we might only
" be sourcing this file, execute them explicitly here
filetype plugin indent on
syntax on
set termguicolors
set number
" remap leader
let mapleader=" "
" remap escape
imap jk <Esc>
cmap jk <Esc>
" remap Y
map Y y$
" paste from the clipboard in insert mode. I've tried this variously as
" <Cmd>norm P<CR>, which ends up with the cursor either one character before
" the end of the pasted text (single-line yank) or at the beginning of the
" pasted text (multi-line), and <C-r>+, which seems to add text line by line,
" resulting in extra indentation and the commenting of subsequent lines if a
" previous line was commented. as noted elsewhere, this method switches modes,
" which can be annoying and slow with mode switch autocmds, but it does at
" least do what I expect vis-a-vis pasting
inoremap <C-v> <C-o>P
" undo/redo in insert mode
inoremap <C-z> <Cmd>norm u<CR>
inoremap <C-y> <Cmd>norm <C-r><CR>
" map to execute the current line
nmap <F6> :exec '!'.getline('.')<CR>
" the same thing but as a vim command instead of a shell command
nmap <F7> :exec getline('.')<CR>
" add an extra line for messages
set cmdheight=2
" turn down timeoutlen (defaults to 1000)
set timeoutlen=500
" Tabs
set softtabstop=2
set shiftwidth=2
set expandtab
" better manual indentation support. note that tab and ctrl-i aren't
" distinguished on most terminal emulators, so to avoid overwriting the jump
" command, don't map tab in normal mode (>> .* does a fine job). we could map
" <s-tab> without any conflicts, but for consistency we don't
vnoremap <Tab> >gv
vnoremap <S-Tab> <gv
" also retain selection w/normal mappings
vnoremap > >gv
vnoremap < <gv
" Open hsplit below current window
set splitbelow
" Open vsplit right of current window
set splitright
" Don't use two spaces after a period when joining lines or formatting
set nojoinspaces
" highlight cursor line in the active window only
augroup CursorLineOnlyInActiveWindow
autocmd!
autocmd VimEnter,WinEnter,BufWinEnter * setlocal cursorline
autocmd WinLeave * setlocal nocursorline
augroup END
" Remap window resizing. This is a little weird, since it isn't window
" placement-aware, but it'll do
nnoremap <C-S-Left> <Cmd>vertical resize -5<CR>
nnoremap <C-S-Right> <Cmd>vertical resize +5<CR>
nnoremap <C-S-Down> <Cmd>resize -2<CR>
nnoremap <C-S-Up> <Cmd>resize +2<CR>
" Search
set ignorecase
set smartcase
" Allows buffer switching without writing. Also for scratch.vim
set hidden
" autoread changed files
set autoread
" Shortcuts for copy/paste to clipboard
" noremap <Leader>y "+y
" noremap <Leader>p "+p
" Yank and paste with the system clipboard
set clipboard+=unnamedplus
" Use very magic mode by default for search
nnoremap / /\v
nnoremap ? ?\v
vnoremap / /\v
vnoremap ? ?\v
" C-h - Find and replace
nnoremap <C-h> :%s/\v//g<left><left><left>
vnoremap <C-h> :s/\v//g<left><left><left>
nnoremap <silent> <leader>o :nohlsearch<CR>
" move lines up and down with M-k/j (or up/down) from
" https://vim.fandom.com/wiki/Moving_lines_up_or_down#Mappings_to_move_lines,
" modified to use map-cmds and thus not change modes, which plays nicely with
" plugins like vim-airline that want to execute expensive autocmds on mode
" changes. see the discussion at
" https://github.com/vim-airline/vim-airline/issues/2440
nnoremap <M-j> <Cmd>m .+1<CR>==
nnoremap <M-k> <Cmd>m .-2<CR>==
inoremap <M-k> <Cmd>m .-2<CR><Cmd>norm ==<CR>
inoremap <M-j> <Cmd>m .+1<CR><Cmd>norm ==<CR>
vnoremap <M-j> <Cmd>call V_Move(0)<CR>
vnoremap <M-k> <Cmd>call V_Move(1)<CR>
nmap <M-Down> <M-j>
nmap <M-Up> <M-k>
imap <M-Down> <M-j>
imap <M-Up> <M-k>
vmap <M-Down> <M-j>
vmap <M-Up> <M-k>
" the following is a rather over-complicating-seeming way of replicating the
" following mappings without changing modes:
"
" vnoremap <A-j> :m '>+1<CR>gv=gv
" vnoremap <A-k> :m '<-2<CR>gv=gv
function! V_Move(up)
let list = [ line('.'), line('v') ]
let upper = min(list)
let lower = max(list)
let cursor_above = line('.') < line('v')
let took_action = 0
" movement and reselection
if a:up
" don't attempt if we're already at the top
if upper > 1
let took_action = 1
exe upper .. ',' .. lower .. 'm ' .. (upper-2)
if cursor_above
exe "norm! " .. (lower-upper) .. "kok"
else
exe "norm! ok"
endif
endif
else
" don't attempt if we're already at the bottom
if lower < line('$')
let took_action = 1
exe upper .. ',' .. lower .. 'm ' .. (lower+1)
if cursor_above
" 0 means move beginning of line, not repeat 0 times, so we need a
" guard here
if lower-upper > 1
exe "norm! o" .. (lower-upper-1) .. "k"
endif
else
exe "norm! oj"
endif
endif
endif
" formatting and reselection
if took_action
exe "norm! =V"
" after formatting, we always end up at the top of the selection. it only
" remains to select the rest of it, if any. as above, guard against 0, which
" has a different meaning
if lower-upper
exe "norm! " .. (lower-upper) .. "j"
endif
endif
endfu
" rebind <Home> to ^ (first non-whitespace character)
nmap <Home> ^
vmap <Home> ^
imap <Home> <Cmd>norm ^<CR>
" make line wrapping nicer. off by default
set nowrap
set virtualedit=block,onemore
nnoremap <silent> <Leader>wr :call ToggleWrap()<CR>
function! ToggleWrap()
if &wrap
echo "Wrap OFF"
setlocal nowrap
setlocal virtualedit=block,onemore
silent! nunmap <buffer> k
silent! nunmap <buffer> j
silent! nunmap <buffer> <Up>
silent! nunmap <buffer> <Down>
silent! nunmap <buffer> <Home>
silent! nunmap <buffer> <End>
silent! iunmap <buffer> <Up>
silent! iunmap <buffer> <Down>
silent! iunmap <buffer> <Home>
silent! iunmap <buffer> <End>
else
echo "Wrap ON"
setlocal wrap linebreak nolist
setlocal virtualedit=onemore
setlocal display+=lastline
noremap <buffer> <silent> k gk
noremap <buffer> <silent> j gj
noremap <buffer> <silent> <Up> gk
noremap <buffer> <silent> <Down> gj
noremap <buffer> <silent> <Home> g^
noremap <buffer> <silent> <End> g<End>
inoremap <buffer> <silent> <Up> <Cmd>norm gk<CR>
inoremap <buffer> <silent> <Down> <Cmd>norm gj<CR>
inoremap <buffer> <silent> <Home> <Cmd>norm g^<CR>
inoremap <buffer> <silent> <End> <Cmd>norm g$<CR>
endif
endfunction
" make window navigation simpler
nnoremap <C-Left> <C-w>h
nnoremap <C-Down> <C-w>j
nnoremap <C-Up> <C-w>k
nnoremap <C-Right> <C-w>l
" on open terminal (:te), start in terminal mode
augroup TermInsert
autocmd!
autocmd TermOpen * startinsert
augroup END
" allow exit to normal mode with esc. I've decided to disable this because it
" conflicts with the behavior of esc in the fzf.vim plugin, and also since I'm
" much more likely to use new tmux panes than the embedded vim terminal anyway
" :tnoremap <Esc> <C-\><C-n>
" always trim whitespace on save, including trailing lines
augroup TrimWhiteSpaceGroup
autocmd!
autocmd BufWritePre * call TrimWhiteSpace()
augroup END
" It's necessary to save and restore the cursor position to avoid jumping
" around
function! TrimWhiteSpace()
let save_cursor = getpos(".")
silent! %s/\($\n\s*\)\+\%$//
silent! %s/\s\+$//
call setpos('.', save_cursor)
endfunction
" save in insert mode
inoremap <C-s> <Cmd>w<CR>
" mappings to cut and paste into the "black hole register"
nnoremap <leader>bc "_c
nnoremap <leader>bd "_d
xnoremap <leader>bc "_c
xnoremap <leader>bd "_d
xnoremap <leader>bp "_dP
" toggle relative line numbers in the gutter
:nnoremap <silent> <C-l> :set relativenumber!<cr>
" close all quickfix and location lists. the mapping is the same as close
" panel in VSCode
nnoremap <silent> <C-j> :windo lcl\|ccl<CR>
" use ripgrep for grep. in general, :Rg or :F, to a lesser extent, are far
" superior alternatives. still, this would be useful if we for some reason
" wanted to populate the quickfix list
set grepprg=rg\ --vimgrep\ --hidden
" Focus on the first floating window
function! s:GotoFirstFloat() abort
for w in range(1, winnr('$'))
let c = nvim_win_get_config(win_getid(w))
" c.relative isn't set for normal windows. see nvim_win_get_config()
if c.focusable && !empty(c.relative)
execute w . 'wincmd w'
break
endif
endfor
endfunction
noremap <silent> <c-w><space> :<c-u>call <sid>GotoFirstFloat()<cr>
set dictionary=/usr/share/dict/words
" close the current buffer without closing its window. switches to the next
" buffer if one exists or edits a new unnamed buffer otherwise
function! s:CloseCurrentBuffer() abort
" count the number of buffers. see https://superuser.com/a/1221514/1264067
if len(getbufinfo({'buflisted':1})) > 1
:bn
else
:enew
endif
" this will fail if the only open buffer is unnamed. we can ignore the
" error with silent!
:silent! bd #
endfunction
command! -nargs=0 Bclose call <sid>CloseCurrentBuffer()
" turn the spell checker on by default
set spell