How to load homebrew on Fish shell?

[andradei]

Output of brew config

Doesn't show until it `brew` is loaded.

Output of brew doctor

Doesn't show until it `brew` is loaded.

Description of issue

It would be nice to have documentation showing how to run homebrew on the Fish shell.
I can run the installation script, but don't know how to run brew shellenv in config.fish to load it.

[SMillerDev]

It should suggest it already in the install command. But if it doesn't, it's exactly the same as for bash, except you need to do eval ( instead of eval $(

[BarbzYHOOL]

no, fish doesn't read .profile file

[apainintheneck]

Which OS are you trying to install Homebrew on?

On Intel Macs, the brew executable got symlinked into /usr/local/bin so no changes were necessary since that's already in everyone's path.

On newer M1 Macs, I ended up adding the following to my config.fish file. It should be suggested in the install script.

eval "$(/opt/homebrew/bin/brew shellenv)"

The install script suggests using .profile by default if the user is not using bash or zsh.

https://github.com/Homebrew/install/blob/35c494693c6d5640bc9892bfcac7eb2433051c7c/install.sh#L1014-L1051

It'd probably make sense to add information about fish too so that the user knows to add it to ~/.config/fish/config.fish. This seems to be the expected place to put those sorts of shell startup scripts and is where asdf and ghcup put that information for fish users for instance.

• https://fishshell.com/docs/current/index.html#configuration

[BarbzYHOOL]

for me it was on linux

[apainintheneck]

The default prefix on Linux is /home/linuxbrew/.linuxbrew so the following probably works.

eval "$(/home/linuxbrew/.linuxbrew/bin/brew shellenv)"

[BarbzYHOOL]

what about putting it in /etc/environment ??

[paldepind]

Note that this only works in Fish 3.4 and greater. For versions below the following can be used (which is the more idiomatic way of doing it anyway):

eval (/home/linuxbrew/.linuxbrew/bin/brew shellenv)

[aldoKelvianto]

Agree with @paldepind, the command substitution in Fish is using (), not "$()".

https://fishshell.com/docs/current/tutorial.html#command-substitutions

[mattmc3]

The proper shell command for Fish is simply brew shellenv | source. If fish_add_path has not been called so that $PATH contains the location of of brew, you can simply use something like this:

set brewcmd (path filter /opt/homebrew/bin/brew /usr/local/bin/brew)[1]
and $brewcmd shellenv | source

[andradei]

This is what I have been using without problems for months after asking this question:

if test -d /home/linuxbrew/.linuxbrew
      # Homebrew is installed on Linux

      set -gx HOMEBREW_PREFIX "/home/linuxbrew/.linuxbrew"
      set -gx HOMEBREW_CELLAR "/home/linuxbrew/.linuxbrew/Cellar"
      set -gx HOMEBREW_REPOSITORY "/home/linuxbrew/.linuxbrew/Homebrew"
      set -gx PATH "/home/linuxbrew/.linuxbrew/bin" "/home/linuxbrew/.linuxbrew/sbin" $PATH
      set -q MANPATH; or set MANPATH ''
      set -gx MANPATH "/home/linuxbrew/.linuxbrew/share/man" $MANPATH
      set -q INFOPATH; or set INFOPATH ''
      set -gx INFOPATH "/home/linuxbrew/.linuxbrew/share/info" $INFOPATH

      # Homebrew asked for this in order to `brew upgrade`
      set -gx HOMEBREW_GITHUB_API_TOKEN {api token goes here, don't remember where that's created}
  else if test -d /opt/homebrew
      # Homebrew is installed on MacOS

      /opt/homebrew/bin/brew shellenv | source
  end
end

[tmwatchanan]

This might be a little bit better.

if test -d /home/linuxbrew/.linuxbrew # Linux
	set -gx HOMEBREW_PREFIX "/home/linuxbrew/.linuxbrew"
	set -gx HOMEBREW_CELLAR "$HOMEBREW_PREFIX/Cellar"
	set -gx HOMEBREW_REPOSITORY "$HOMEBREW_PREFIX/Homebrew"
else if test -d /opt/homebrew # MacOS
	set -gx HOMEBREW_PREFIX "/opt/homebrew"
	set -gx HOMEBREW_CELLAR "$HOMEBREW_PREFIX/Cellar"
	set -gx HOMEBREW_REPOSITORY "$HOMEBREW_PREFIX/homebrew"
end
fish_add_path -gP "$HOMEBREW_PREFIX/bin" "$HOMEBREW_PREFIX/sbin";
! set -q MANPATH; and set MANPATH ''; set -gx MANPATH "$HOMEBREW_PREFIX/share/man" $MANPATH;
! set -q INFOPATH; and set INFOPATH ''; set -gx INFOPATH "$HOMEBREW_PREFIX/share/info" $INFOPATH;